// Parametric object flower-like surface. 
// Copyright (c) 08/2004 by Wolfgang Wieser. 

#include "functions.inc"

global_settings { assumed_gamma 2.2 }
//light_source { <-0.4,0.2,-0.3>*20, rgb <2,2,2>/2 }
light_source { <0.2,0.3,-0.3>*20*5, rgb <2,2,2>/1.3 }

#declare m=3;
parametric {
	function { u*sin(v+sqrt(u))*(1-0.001*sqrt(u)) }
	function { 15*sqrt(pow(sin(m*v+0.1*sqrt(u))*    sin(u*0.5-0.1*sqrt(v))/3, 2)+
	                   pow(cos(m*v+0.1*sqrt(u))*m/u*sin(u*0.5-0.1*sqrt(v))/3, 2)) 
	           +sqrt(u)-1/pow(u,3) }
	function { u*cos(v+sqrt(u))*(1-0.001*sqrt(u)) }
	<0.001,0>, <15,2*pi>
	contained_by {  sphere { 0, 20 }  }
	precompute 14 x,y,z
	accuracy 0.0001
	
	pigment {
		gradient y
		color_map {
			[0 rgb <0,1,0>]
			[.5 rgb <0,0.71,0.71>]
			[1 rgb <0,0,1>]
		}
		translate 0.2*y
		scale 9
	}
	
	rotate 180*y
	scale 1.2
	no_shadow
}

//sphere { 0, 20  pigment { rgbf 0.9 } }

plane { y,-12 pigment { checker rgb 0.7 rgb 0.8 scale 5 }}

//camera { location <0,0.6,-1>*8.3*4 up y  look_at <0,0,0> }
camera { location <0,0.6,-1>*8.3*4 up y  look_at <0,2,0>  translate 2*y }